A class to provide compression features to Jervis, specifically GZip. GZip provides groovy-like leftShift for compressing strings. This class also uses maximum compression by default and provides an easy means to change the compression level.

Sample usage

To run this example, clone Jervis and execute ./gradlew console to bring up a Groovy Console with the classpath set up.

Write out a compressed file

import net.gleske.jervis.tools.GZip

new File('test.gz').withOutputStream { OutputStream os ->
    try {
        (new GZip(os)).withCloseable {
            it << 'hello world\n\nMy friend\n'
        }
    } finally {
        os.close()
    }
}

Upload a compressed file

This example uploads compressed data directly to Sonatype Nexus. Compare this example with SimpleRestService

import net.gleske.jervis.tools.GZip
import net.gleske.jervis.tools.SecurityIO

String username = 'your user'
String password = 'your pass'

URL api_url = new URL('http://localhost:8081/repository/hosted-raw-repo/file.gz')
HttpURLConnection response = api_url.openConnection().with { conn ->
    conn.doOutput = true
    conn.setRequestMethod('PUT')
    conn.setRequestProperty('Authorization', "Basic " + SecurityIO.encodeBase64("${username}:${password}"))
    conn.setRequestProperty('Accept', '*/*')
    conn.setRequestProperty('Expect', '100-continue')
    conn.outputStream.withCloseable { nexus_os ->
        new GZip(nexus_os).withCloseable { gzip ->
            gzip << 'hello world\n\nMy friend\n'
        }
    }
    conn
}
// getting the response code completes the setup and makes the network connection
assert response.responseCode == 201

Base64 encoded GZip compressed data

Some APIs, such as uploading to GitHub analysis as SARIF data, may require compressing data and including the compressed payload as part of a plain text JSON request. This example highlights getting base64 encoded compressed data. You can find a more advanced example in GitHub class documentation.

import net.gleske.jervis.tools.GZip
import net.gleske.jervis.tools.SecurityIO
import java.util.zip.GZIPInputStream

ByteArrayOutputStream compressed = new ByteArrayOutputStream()
// best speed compression
new GZip(compressed, 1).withCloseable {
    it << 'hello'
    it << ' world'
}

// COMPRESSED data encoded as base64
String data = SecurityIO.encodeBase64(compressed.toByteArray())

// DECOMPRESS example
ByteArrayOutputStream plain = new ByteArrayOutputStream()
new ByteArrayInputStream(SecurityIO.decodeBase64Bytes(data)).withCloseable { is ->
    new GZIPInputStream(is).withCloseable { gunzip ->
        plain << gunzip
    }
}
assert plain.toString() == 'hello world'